串行数模转换实验

串行数模转换实验

一． 实验目的
学会使用D/A 转换器生成用户所需要的波形。
二． 实验设备及器件
IBM PC 机 一台
DP-51PROC 单片机综合仿真实验仪 一台
双踪示波器 一台
三． 实验内容
1． 设计软件程序，用单片机的I/O 口控制TLC5620 实现D/A 转换，使其通道1 产
生一个三角波，而通道2 产生一个和通道1 周期、幅度均相同的方波。
2． 连接线路，调整TLC5620 的参考电压为2.6V，运行程序，用双踪示波器观察产生
的波形。
四． 实验要求
实验前阅读有关TLC5620 的数据手册，并了解TLC5620 的4 种时序图，以及产
生波形幅度的计算方法。
五． 实验步骤
1． 短接B7 区的电源供给跳线JP16，调节B7 区的电位器W3，使其输出接线柱Verf
的电压为2.6V。
2． 将A2 区P16、P17、T0、T1 分别连接到B9 区的CLK、DAT、LDAC、LOAD，
将B7 区Verf 连接到B9 区REF 接线柱，短接B9 区电源跳线JP13。
3． 运行光盘中的相应程序，用双踪示波器的两个探头观察DACA、DACB 输出的波形。
六． 实验预习要求
认真预习本节实验内容，按照实验的要求提前做好实验准备工作。
七． 实验参考程序
SCLA BIT P1.6
SDAA BIT P1.7
LOAD BIT P3.5
LDAC BIT P3.4
VOUTA DATA 30H
VOUTB DATA 31H
ORG 8000H
AJMP MAIN
ORG 8100H

MAIN:
MOV SP,#60H
NOP
CLR SCLA
CLR SDAA
SETB LOAD
SETB LDAC
MOV R3,#0A2H
MOV R4,#00H
MOV VOUTA,#00H
MOV R5,#0A2H
MOV R6,#00H
MOV VOUTB,#00H
DACHANG:
MOV R1,#01H
MOV R2,VOUTA
LCALL DAC5620
DJNZ R3,CONTINUEA
MOV R3,#0A2H
MOV A,R4
CPL A
MOV R4,A
CONTINUEA:
CJNE R4,#0FFH,CONTINUEB
DEC R2
SJMP CONTINUEC
CONTINUEB:
INC R2
CONTINUEC:
MOV VOUTA,R2
MOV R1,#03H
MOV R2,VOUTB
LCALL DAC5620
DJNZ R5,CONTINUED
MOV R5,#0A2H
MOV A,R6
CPL A
MOV R6,A
CONTINUED:
CJNE R6,#0FFH,CONTINUEE
MOV R2,#0A2H
SJMP CONTINUEF
CONTINUEE:
MOV R2,#00H

CONTINUEF:
MOV VOUTB,R2
LJMP DACHANG
;=============================================
; 函数名称: DAC5620
; 功能描述: TI 公司8 位4 通DAC 芯片TLC5620 的控制时序
; 入口参数: R1(通道选择和幅度增量)、R2(转换电压的数字值，公式中的CODE)
; 出口参数: 无
; 占用资源: ACC、R1、R2
; 全局变量: 无
; 调用模块: SENDBYTE
; 日 期: 2004-10-27
; 备 注: 使用双8 位传输控制模式，使用LDAC 下降沿锁存数据输入
;=============================================
DAC5620:
MOV A,R1
CLR SCLA
MOV R7,#08H
LCALL SENDBYTE
MOV A,R2
CLR SCLA
MOV R7,#08H
LCALL SENDBYTE
CLR LOAD
SETB LOAD
CLR LDAC
SETB LDAC
RET
SENDBYTE:
SETB SCLA
RLC A
MOV SDAA,C
CLR SCLA
DJNZ R7,SENDBYTE
RET
END